confOS/windows11.bat

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

SET "repo=https://git.mylloon.fr/Anri/confOS/raw/branch/main"

:: Executed as normal user
fltmc >NUL 2>&1 || (
    :: === Install Spotify ==
    DEL "%APPDATA%\Spotify"
    CMD /c "%HOMEPATH%\Documents\Local\blockthespot.bat"

    :: Start as administrator
    PowerShell Start -Verb RunAs '%0' 2>NUL || (
        EXIT 1
    )
    EXIT 0
)
:: Executed as admin user

:: === Right click of Windows 10 ==
REG ADD "HKEY_CURRENT_USER\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}\InprocServer32" /f /ve

:: === Disabling widgets ==
REG ADD "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Dsh" /v AllowNewsAndInterests /t REG_DWORD /d 00000000 /f

:: === Disabling hibernation (prevents computer to really shutdown) ==
REG ADD "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\Session Manager\Power" /v HiberbootEnabled /t REG_DWORD /d 00000000 /f
powercfg /H off

:: === Disabling the SysMain service (preload some apps in memory) ==
sc stop "SysMain" & sc config "SysMain" start=disabled

:: === Added confirmation when trashing ==
REG ADD "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v ConfirmFileDelete /t REG_DWORD /d 00000001 /f

:: === Don't create a Zone:Identify ==
REG ADD "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\Attachments" /v SaveZoneInformation /t REG_DWORD /d 00000001 /f

:: === Disables memory integrity ==
:: see https://support.microsoft.com/en-us/windows/options-to-optimize-gaming-performance-in-windows-11-a255f612-2949-4373-a566-ff6f3f474613
REG ADD "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\DeviceGuard\Scenarios\HypervisorEnforcedCodeIntegrity" /v Enabled /t REG_DWORD /d 00000000 /f

:: === Disables sticky keys ==
REG ADD "HKEY_CURRENT_USER\Control Panel\Accessibility\StickyKeys" /v Flags /t REG_SZ /d 506 /f

:: === Inverts the default shortcuts for changing input language and keyboard layout ==
REG ADD "HKEY_CURRENT_USER\Keyboard Layout\toggle" /v "Hotkey" /t REG_SZ /d 1 /f
REG ADD "HKEY_CURRENT_USER\Keyboard Layout\toggle" /v "Language Hotkey" /t REG_SZ /d 2 /f

:: === Disable Game Bar ==
REG ADD "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\GameDVR" /v AppCaptureEnabled /t REG_DWORD /d 00000000 /f
REG ADD "HKEY_CURRENT_USER\System\GameConfigStore" /v GameDVR_Enabled /t REG_DWORD /d 00000000 /f

:: === Edge tweaks ==
REG ADD "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Edge" /v HubsSidebarEnabled /t REG_DWORD /d 00000000 /f
REG ADD "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Edge" /v ShowRecommendationsEnabled /t REG_DWORD /d 00000000 /f

:: === WinGet ==
:: Auto accept ToT
ECHO Y | winget list >NUL
SET "pmi=winget install -he"

:: C++ Libraries
SET ^"cpp_libs=Microsoft.VCRedist.2005.x86 Microsoft.VCRedist.2005.x64 ^
               Microsoft.VCRedist.2008.x86 Microsoft.VCRedist.2008.x64 ^
               Microsoft.VCRedist.2010.x86 Microsoft.VCRedist.2010.x64 ^
               Microsoft.VCRedist.2012.x86 Microsoft.VCRedist.2012.x64 ^
               Microsoft.VCRedist.2013.x86 Microsoft.VCRedist.2013.x64 ^
               Microsoft.VCRedist.2015+.x86 Microsoft.VCRedist.2015+.x64"

for %%i in (!cpp_libs!) do (
    !pmi! %%i
)

:: Applications
SET ^"apps=Discord.Discord Mozilla.Firefox 7zip.7zip Valve.Steam Parsec.Parsec ^
           voidtools.Everything.Lite VideoLAN.VLC File-New-Project.EarTrumpet ^
           EclipseAdoptium.Temurin.17.JDK EclipseAdoptium.Temurin.8.JDK ^
           Microsoft.VisualStudioCode GIMP.GIMP DuongDieuPhap.ImageGlass ^
           ONLYOFFICE.DesktopEditors HeroicGamesLauncher.HeroicGamesLauncher ^
           OBSProject.OBSStudio Xournal++.Xournal++ Microsoft.PowerToys ^
           OpenWhisperSystems.Signal HandBrake.HandBrake Front.scrcpy+ ^
           KDE.KDEConnect PrismLauncher.PrismLauncher Microsoft.PowerShell ^
           RiotGames.LeagueOfLegends.EUW RiotGames.Valorant.EU"

for %%i in (!apps!) do (
    !pmi! %%i
)

:: Install Vencord
TASKKILL /im Discord.exe /F
PowerShell -Command "$link = 'https://github.com/Vencord/Installer/releases/latest/download/VencordInstallerCli.exe';" ^
                    "$file = 'vencord.exe';" ^
                    "$outfile = Join-Path -Path $env:TEMP -ChildPath $file;" ^
                    "Invoke-WebRequest -Uri $link -OutFile $outfile;" ^
                    "cd $env:TEMP;" ^
                    "ECHO 1| & $outfile -install"

:: Install WSL
wsl --install --no-launch
wsl --unregister Ubuntu

:: === Firefox configuration ==
"%ProgramFiles%\Mozilla Firefox\firefox.exe"
TASKKILL /im firefox.exe /F

FOR /F %%i IN ('dir /B /S ^"%APPDATA%\Mozilla\Firefox\Profiles\*.default-release^"') DO SET "vbc=%%i"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/.mozilla/firefox/user.js -OutFile '!vbc!\user.js'"

PowerShell -Command "Invoke-WebRequest -Uri !repo!/.mozilla/firefox/extensions/Dark-Reader-Settings.json -OutFile '%HOMEPATH%\Downloads\Dark-Reader-Settings.json'"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/.mozilla/firefox/extensions/SponsorBlockConfig.json -OutFile '%HOMEPATH%\Downloads\SponsorBlockConfig.json'"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/.mozilla/firefox/extensions/auto-tab-discard-preferences.json -OutFile '%HOMEPATH%\Downloads\auto-tab-discard-preferences.json'"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/.mozilla/firefox/extensions/libredirect-settings.json -OutFile '%HOMEPATH%\Downloads\libredirect-settings.json'"
ECHO La configuration des differents Addons de Firefox est presente dans le dossier %HOMEPATH%\Downloads.

:: === User Diag for drivers ==
ECHO Installe les pilotes, pour connaitre la liste des pilotes, utilise UserDiag https://userdiag.com/download

:: === W10Privacy ==
PowerShell -Command "Invoke-WebRequest -Uri !repo!/W10Privacy.ini -OutFile '%HOMEPATH%\Downloads\W10Privacy.ini'"
ECHO Ensuite, utilise W10Privacy (https://www.w10privacy.de/deutsch-start/download/) avec le fichier present dans %HOMEPATH%\Downloads (version 4.1.2.1).

:: === Modules ==
PowerShell -Command "Install-PackageProvider -Name NuGet -Force"
PowerShell -Command "Install-Module -Name PSWindowsUpdate -Force"

:: === Scripts ==
MKDIR %HOMEPATH%\Documents\Local
PowerShell -Command "Invoke-WebRequest -Uri !repo!/windows/ctmpf.bat -OutFile '%HOMEPATH%\Documents\Local\ctmpf.bat'"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/windows/blockthespot.bat -OutFile '%HOMEPATH%\Documents\Local\blockthespot.bat'"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/windows/update.bat -OutFile '%HOMEPATH%\Documents\Local\update.bat'"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/windows/fix_nvidia_wsl.bat -OutFile '%HOMEPATH%\Documents\Local\fix_nvidia_wsl.bat'"

:: === Install OpenTabletDriver ==
:: Download
PowerShell -Command "Invoke-WebRequest -Uri https://opentabletdriver.net/Release/Download/OpenTabletDriver.win-x64.zip -OutFile '%HOMEPATH%\Downloads\OpenTabletDriver.win-x64.zip'"
:: Extract
PowerShell -Command "Expand-Archive -Path '%HOMEPATH%\Downloads\OpenTabletDriver.win-x64.zip' -DestinationPath '%ProgramFiles%\OpenTabletDriver'"
:: Create shortcut
PowerShell -Command "& { $WshShell = New-Object -comObject WScript.Shell; $Shortcut = $WshShell.CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\OpenTabletDriver.lnk'); $Shortcut.TargetPath = '%ProgramFiles%\OpenTabletDriver\OpenTabletDriver.UX.Wpf.exe'; $Shortcut.Save() }"

:: WindowsInk
PowerShell -Command "Invoke-WebRequest -Uri https://github.com/X9VoiD/vmulti-bin/releases/download/v1.0/Driver.zip -OutFile '%HOMEPATH%\Downloads\Driver-VMulti.zip'"
:: Extract
PowerShell -Command "Expand-Archive -Path '%HOMEPATH%\Downloads\Driver-VMulti.zip' -DestinationPath '%HOMEPATH%\Downloads\Driver-VMulti'"
:: Install driver
CALL %HOMEPATH%\Downloads\Driver-VMulti\64\install_hiddriver.bat
:: Download plugin
PowerShell -Command "Invoke-WebRequest -Uri https://github.com/X9VoiD/VoiDPlugins/releases/latest/download/WindowsInk.zip -OutFile '%HOMEPATH%\Downloads\WindowsInk.zip'"
:: Extract plugin
PowerShell -Command "Expand-Archive -Path '%HOMEPATH%\Downloads\WindowsInk.zip' -DestinationPath '%LOCALAPPDATA%\OpenTabletDriver\Plugins\Windows Ink'"

:: === Miscellaneous ==
:: Rename shortcut for Minecraft
RENAME "%APPDATA%\Microsoft\Windows\Start Menu\Programs\Prism Launcher.lnk" Minecraft.lnk

:: Startup OBS replay buffer
PowerShell -Command "$WshShell = New-Object -COM WScript.Shell;" ^
                    "$Shortcut = $WshShell.CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\Startup\OBS.lnk');" ^
                    "$Shortcut.TargetPath = '%ProgramFiles%\obs-studio\bin\64bit\obs64.exe';" ^
                    "$Shortcut.WorkingDirectory = '%ProgramFiles%\obs-studio\bin\64bit';" ^
                    "$Shortcut.Arguments = '--disable-missing-files-check --minimize-to-tray --startreplaybuffer --profile ""ReplayBuffer"""" --scene ""ReplayBuffer""""';" ^
                    "$Shortcut.Save()"
:: Default shortcut should start default profile
PowerShell -Command "$WshShell = New-Object -COM WScript.Shell;" ^
                    "$Shortcut = $WshShell.CreateShortcut('%ProgramData%\Microsoft\Windows\Start Menu\Programs\OBS Studio\OBS Studio (64bit).lnk');" ^
                    "$Shortcut.TargetPath = '%ProgramFiles%\obs-studio\bin\64bit\obs64.exe';" ^
                    "$Shortcut.WorkingDirectory = '%ProgramFiles%\obs-studio\bin\64bit';" ^
                    "$Shortcut.Arguments = '--profile ""ANRI GAMING (PROFIL)""""';" ^
                    "$Shortcut.Save()"

ECHO Fais un tour des parametres Windows, apres avoir fait toutes les mises a jour disponible sur le PC.
ECHO Enfin, redemarre l'ordinateur

PAUSE
EXIT /B