confOS/windows/clean.bat

@ECHO OFF

:: Start as administrator
fltmc >NUL 2>&1 || (
  PowerShell Start -Verb RunAs '%0' 2>NUL || (
    EXIT 1
  )
  EXIT 0
)

ECHO CTMPF :: Clean TeMPorary Files

:: Empty the user's temp folder
ECHO Suppression des fichiers dans %TEMP%...
DEL /S /F /Q %LOCALAPPDATA%\Temp\* 2>NUL
RMDIR /S /Q "%TEMP%" 2>NUL

:: Empty the system's temp folder
ECHO Suppression des fichiers dans %WINDIR%\Temp...
RMDIR /S /Q "%WINDIR%\Temp" 2>NUL

:: Empty the Prefetch folder
ECHO Suppression des fichiers dans %WINDIR%\Prefetch...
RMDIR /S /Q "%WINDIR%\Prefetch" 2>NUL

:: Remove old Windows installation
if exist "%SYSTEMDRIVE%\Windows.old" (
  ECHO Supprime l'ancienne installation de Windows dans %SYSTEMDRIVE%\Windows.old...
  TAKEOWN /f "%SYSTEMDRIVE%\Windows.old" /a /r /d y
  ICACLS "%SYSTEMDRIVE%\Windows.old" /grant administrators:F /t
  RMDIR /S /Q "%SYSTEMDRIVE%\Windows.old"
)

:: Empty useless files of Windows
ECHO Suppression des fichiers dans C:\$WinREAgent...
RMDIR /S /Q "C:\$WinREAgent" 2>NUL
ECHO Suppression des fichiers dans C:\Recovery...
RMDIR /S /Q "C:\Recovery" 2>NUL

:: Empty AMD installer files
ECHO Suppression des fichiers dans C:\AMD...
RMDIR /S /Q "C:\AMD" 2>NUL

:: Empty Windows generated logs
ECHO Suppression des fichiers dans C:\PerfLogs...
RMDIR /S /Q "C:\PerfLogs" 2>NUL

:: Delete Dump
ECHO Suppression des logs de la pile C:\DumpStack.log...
DEL /Q "C:\DumpStack.log" 2>NUL

:: Empty NVidia shader caches
ECHO Supprime les caches NVidia
DEL /S /F /Q %LOCALAPPDATA%Low\NVIDIA\PerDriverVersion\DXCache\* 2>NUL
DEL /S /F /Q %LOCALAPPDATA%\NVIDIA\GLCache\* 2>NUL

:: Clean disks
ECHO Nettoyage de l'ordinateur avec cleanmgr...
CD %WINDIR%\system32
cleanmgr /AUTOCLEAN
cleanmgr /VERYLOWDISK

EXIT /B