@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

SET "repo=https://git.mylloon.fr/Anri/confOS/raw/branch/main"
SET "local=%HOMEPATH%\Documents\Local"

MKDIR "!local!" 2>NUL

:: => NO-ADMIN RIGHTS <=

fltmc >NUL 2>&1 || (
  ECHO Please wait until the administrator popup appears

  :: === Update winget to latest version ==
  PowerShell -Command "" ^
    "Invoke-WebRequest -Uri https://aka.ms/getwinget -OutFile winget.msixbundle;" ^
    "Add-AppPackage -ForceApplicationShutdown .\winget.msixbundle;" ^
    "del .\winget.msixbundle"


  :: === Install Spotify ==
  PowerShell -Command "Invoke-WebRequest -Uri !repo!/windows/blockthespot.bat -OutFile '!local!\blockthespot.bat'"
  DEL "%APPDATA%\Spotify"
  ECHO Y| CMD /c "!local!\blockthespot.bat" yes
  PowerShell -Command "Stop-Process -Name Spotify -ErrorAction SilentlyContinue"

  :: Start as administrator
  PowerShell Start -Verb RunAs '%0' 2>NUL || (
    EXIT 1
  )
  EXIT 0
)


:: => ADMIN RIGHTS <=

:: === Registery modifications ==
ECHO Registery entries...
:: Right click of Windows 10
:: REG ADD "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}\InprocServer32" /f /ve

:: Disabling widgets
REG ADD "HKLM\Software\Policies\Microsoft\Dsh" /v AllowNewsAndInterests /t REG_DWORD /d 0 /f

:: Disabling hibernation (prevents computer to really shutdown)
REG ADD "HKLM\System\CurrentControlSet\Control\Session Manager\Power" /v HiberbootEnabled /t REG_DWORD /d 0 /f
powercfg /H off

:: Disabling the SysMain service (preload some apps in memory)
sc stop "SysMain" & sc config "SysMain" start=disabled

:: Added confirmation when trashing
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v ConfirmFileDelete /t REG_DWORD /d 1 /f

:: Don't create Zone.Identifier
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Attachments" /v SaveZoneInformation /t REG_DWORD /d 1 /f

:: Disables memory integrity
:: see https://support.microsoft.com/en-us/windows/options-to-optimize-gaming-performance-in-windows-11-a255f612-2949-4373-a566-ff6f3f474613
REG ADD "HKLM\System\CurrentControlSet\Control\DeviceGuard\Scenarios\HypervisorEnforcedCodeIntegrity" /v Enabled /t REG_DWORD /d 0 /f

:: Disables sticky keys
REG ADD "HKCU\Control Panel\Accessibility\StickyKeys" /v Flags /t REG_SZ /d 506 /f

:: Remove default shortcuts for changing input language and keyboard layout
:: WIN+Space still available
REG ADD "HKCU\Keyboard Layout\toggle" /v "Hotkey" /t REG_SZ /d 3 /f
REG ADD "HKCU\Keyboard Layout\toggle" /v "Language Hotkey" /t REG_SZ /d 3 /f

:: Disable Game Bar
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\GameDVR" /v AppCaptureEnabled /t REG_DWORD /d 0 /f
REG ADD "HKCU\System\GameConfigStore" /v GameDVR_Enabled /t REG_DWORD /d 0 /f

:: Edge tweaks
REG ADD "HKLM\Software\Policies\Microsoft\Edge" /v HubsSidebarEnabled /t REG_DWORD /d 0 /f
REG ADD "HKLM\Software\Policies\Microsoft\Edge" /v ShowRecommendationsEnabled /t REG_DWORD /d 0 /f
REG ADD "HKLM\Software\Policies\Microsoft\Edge" /v SpotlightExperiencesAndRecommendationsEnabled /t REG_DWORD /d 0 /f

:: Disable Windows Copilot
REG ADD "HKCU\Software\Policies\Microsoft\Windows\WindowsCopilot" /v TurnOffWindowsCopilot /t REG_DWORD /d 1 /f

:: Disable checkboxes in explorer
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v AutoCheckSelect /t REG_DWORD /d 0 /f

:: Disable web search in start menu
:: TODO: Need testing
:: REG ADD "HKCU\Software\Policies\Microsoft\Windows\Explorer" /v DisableSearchBoxSuggestions /t REG_DWORD /d 1 /f

:: Disable ad in file explorer
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSyncProviderNotifications /t REG_DWORD /d 0 /f

:: Disable ad in login screen
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v RotatingLockScreenOverlayEnabled /t REG_DWORD /d 0 /f
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v SubscribedContent-338387Enabled /t REG_DWORD /d 0 /f

:: Disable ad in settings and notifications
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v SubscribedContent-338393Enabled /t REG_DWORD /d 0 /f
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v SubscribedContent-353694Enabled /t REG_DWORD /d 0 /f
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v SubscribedContent-353696Enabled /t REG_DWORD /d 0 /f

:: Disable ad at boot
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\UserProfileEngagement" /v ScoobeSystemSettingEnabled /t REG_DWORD /d 0 /f
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v SubscribedContent-310093Enabled /t REG_DWORD /d 0 /f

:: Disable targeted ad
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\AdvertisingInfo" /v Enabled /t REG_DWORD /d 0 /f
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Privacy" /v TailoredExperiencesWithDiagnosticDataEnabled /t REG_DWORD /d 0 /f

:: Disable ad in start menu
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Start_IrisRecommendations /t REG_DWORD /d 0 /f


:: === Install optional features ==
PowerShell -Command "" ^
  "Get-WindowsCapability -Online -Name 'App.WirelessDisplay.Connect*' | Add-WindowsCapability -Online"


:: === WinGet ==
:: Auto accept ToT
ECHO Y | winget list >NUL
SET "pmi=winget install --silent --exact"

:: C++ libraries
SET ^"cpp_libs=^
  Microsoft.VCRedist.2005.x86 Microsoft.VCRedist.2005.x64 ^
  Microsoft.VCRedist.2008.x86 Microsoft.VCRedist.2008.x64 ^
  Microsoft.VCRedist.2010.x86 Microsoft.VCRedist.2010.x64 ^
  Microsoft.VCRedist.2012.x86 Microsoft.VCRedist.2012.x64 ^
  Microsoft.VCRedist.2013.x86 Microsoft.VCRedist.2013.x64 ^
  Microsoft.VCRedist.2015+.x86 Microsoft.VCRedist.2015+.x64"

ECHO C++ libraries...
for %%i in (!cpp_libs!) do (
  !pmi! %%i
)

:: .NET libraries
SET ^"net_libs=^
  Microsoft.DotNet.DesktopRuntime.3_1 Microsoft.DotNet.SDK.3_1 ^
  Microsoft.DotNet.DesktopRuntime.5 Microsoft.DotNet.SDK.5 ^
  Microsoft.DotNet.DesktopRuntime.6 Microsoft.DotNet.SDK.6 ^
  Microsoft.DotNet.DesktopRuntime.7 Microsoft.DotNet.SDK.7 ^
  Microsoft.DotNet.DesktopRuntime.8 Microsoft.DotNet.SDK.8"

ECHO .NET libraries...
for %%i in (!net_libs!) do (
  !pmi! %%i
)

:: Java dev kits
SET ^"java_jdk=^
  Oracle.JavaRuntimeEnvironment EclipseAdoptium.Temurin.17.JDK"

ECHO JDK...
for %%i in (!java_jdk!) do (
  !pmi! %%i
)

:: Drivers
SET ^"java_jdk=^
  Nvidia.CUDA"

ECHO Drivers...
for %%i in (!java_jdk!) do (
  !pmi! %%i
)

:: Applications
SET ^"apps=^
  Discord.Discord Spotify.Spotify Mozilla.Firefox M2Team.NanaZip Parsec.Parsec ^
  voidtools.Everything.Lite VideoLAN.VLC Obsidian.Obsidian GIMP.GIMP ^
  Microsoft.VisualStudioCode Bitwarden.Bitwarden DuongDieuPhap.ImageGlass ^
  TheDocumentFoundation.LibreOffice Armin2208.WindowsAutoNightMode  ^
  OBSProject.OBSStudio Xournal++.Xournal++ Microsoft.PowerToys KDE.KDEConnect ^
  OpenWhisperSystems.Signal TenacityTeam.Tenacity Microsoft.PowerShell"

ECHO Apps...
for %%i in (!apps!) do (
  !pmi! %%i
)

:: Games related - Osu! separated because of exclamation mark escaping
SET ^"games=^
  RiotGames.LeagueOfLegends.EUW RiotGames.Valorant.EU Valve.Steam ^
  HeroicGamesLauncher.HeroicGamesLauncher PrismLauncher.PrismLauncher ^
  Ryujinx.Ryujinx"

ECHO Games...
!pmi! Peppy.Osu^^!
for %%i in (!games!) do (
  !pmi! %%i
)


:: === Ryujinx shortcut ==
:: Installed from winget as a portable app
PowerShell -Command "" ^
  "$WshShell = New-Object -comObject WScript.Shell;" ^
  "$exe = (Get-ChildItem $env:LOCALAPPDATA\Microsoft\WinGet\Packages\Ryujinx.Ryujinx_Microsoft.Winget.*\publish\Ryujinx.exe).FullName;" ^
  "$Shortcut = $WshShell.CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\Ryujinx.lnk');" ^
  "$Shortcut.TargetPath = $exe;" ^
  "$Shortcut.Save()"


:: === Install WSL ==
ECHO WSL...
wsl --install --no-distribution


:: === Activate Windows ==
:: TODO: Fix command, see https://massgrave.dev/command_line_switches#uses-in-powershell-one-liner
:: PowerShell -Command "" ^
::   "& ([ScriptBlock]::Create((irm https://mass grave.dev/get)))" ^
::   "/HWID"


:: === Modules for Windows Update ==
PowerShell -Command "Install-PackageProvider -Name NuGet -Force"
PowerShell -Command "Install-Module -Name PSWindowsUpdate -Force"


:: === Scripts from ./windows directory ==
PowerShell -Command "Invoke-WebRequest -Uri !repo!/windows/ctmpf.bat -OutFile '!local!\ctmpf.bat'"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/windows/update.bat -OutFile '!local!\update.bat'"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/windows/fix_nvidia_wsl.bat -OutFile '!local!\fix_nvidia_wsl.bat'"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/windows/vencord_installer.bat -OutFile '!local!\vencord_installer.bat'"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/windows/fix_mihoyo_shortcut.bat -OutFile '!local!\fix_mihoyo_shortcut.bat'"
:: PowerShell -Command "Invoke-WebRequest -Uri !repo!/windows/fix_obs_shortcut.bat -OutFile '!local!\fix_obs_shortcut.bat'"


:: === Geek Uninstaller ==
ECHO Geek Uninstaller...
PowerShell -Command "" ^
  "$archive = '%TEMP%\geek.zip';" ^
  "Invoke-WebRequest -Uri https://geekuninstaller.com/geek.zip -OutFile $archive;" ^
  "Expand-Archive -Path $archive -DestinationPath '%ProgramFiles%\Geek Uninstaller' -Force;" ^
  "$WshShell = New-Object -comObject WScript.Shell;" ^
  "$Shortcut = $WshShell.CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\Geek Uninstaller.lnk');" ^
  "$Shortcut.TargetPath = '%ProgramFiles%\Geek Uninstaller\geek.exe';" ^
  "$Shortcut.Save()"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\geek" /f /v DisplayName /t REG_SZ /d "Geek Uninstaller"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\geek" /f /v InstallLocation /t REG_SZ /d "%ProgramFiles%\Geek Uninstaller"


:: === LosslessCut ==
ECHO LosslessCut...
PowerShell -Command "" ^
  "$archive = 'LosslessCut-win-x64.7z';" ^
  "$link = 'https://github.com/mifi/lossless-cut/releases/latest/download/' + $archive;" ^
  "$outfile = Join-Path -Path $env:TEMP -ChildPath $archive;" ^
  "Invoke-WebRequest -Uri $link -OutFile $outfile;" ^
  "cd $env:TEMP;" ^
  "& $env:ProgramFiles\7-Zip\7z.exe x $archive -o'%ProgramFiles%\LosslessCut' -y;" ^
  "$WshShell = New-Object -comObject WScript.Shell;" ^
  "$Shortcut = $WshShell.CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\LosslessCut.lnk');" ^
  "$Shortcut.TargetPath = '%ProgramFiles%\LosslessCut\LosslessCut.exe';" ^
  "$Shortcut.Save();" ^
  "Remove-Item -Force $archive"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\LosslessCut" /f /v DisplayName /t REG_SZ /d "LosslessCut"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\LosslessCut" /f /v InstallLocation /t REG_SZ /d "%ProgramFiles%\LosslessCut"


:: === DSR ==
ECHO DSR...
PowerShell -Command "" ^
  "$releases = 'https://git.mylloon.fr/api/v1/repos/Anri/dsr/releases/latest';" ^
  "$link = (Invoke-WebRequest $releases | ConvertFrom-Json)[0].assets.browser_download_url;" ^
  "$archive = '%TEMP%\dsr.zip';" ^
  "Invoke-WebRequest -Uri $link -OutFile $archive;" ^
  "Remove-Item '%LOCALAPPDATA%\DSR' -Recurse -ErrorAction SilentlyContinue;" ^
  "Expand-Archive -Path $archive -DestinationPath '%LOCALAPPDATA%\DSR' -Force;" ^
  "Move-Item -Path '%LOCALAPPDATA%\DSR\dsr-win32-x64\*' -Destination '%LOCALAPPDATA%\DSR' -Force;" ^
  "Remove-Item '%LOCALAPPDATA%\DSR\dsr-win32-x64';" ^
  "$WshShell = New-Object -comObject WScript.Shell;" ^
  "$Shortcut = $WshShell.CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\DSR.lnk');" ^
  "$Shortcut.TargetPath = '%LOCALAPPDATA%\DSR\dsr.exe';" ^
  "$Shortcut.Save();" ^
  "Remove-Item -Force $archive"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\dsr" /f /v DisplayName /t REG_SZ /d "DSR"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\dsr" /f /v InstallLocation /t REG_SZ /d "%LOCALAPPDATA%\DSR"


:: === Vencord ==
:: Use already downloaded script
CMD /c "!local!\vencord_installer.bat" yes


:: === OpenTabletDriver ==
ECHO OpenTabletDriver...
PowerShell -Command "" ^
  "$archive = '%TEMP%\OpenTabletDriver.win-x64.zip';" ^
  "Invoke-WebRequest -Uri https://github.com/OpenTabletDriver/OpenTabletDriver/releases/latest/download/OpenTabletDriver.win-x64.zip -OutFile $archive;" ^
  "Expand-Archive -Path $archive -DestinationPath '%ProgramFiles%\OpenTabletDriver' -Force;" ^
  "$WshShell = New-Object -comObject WScript.Shell;" ^
  "$Shortcut = $WshShell.CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\OpenTabletDriver.lnk');" ^
  "$Shortcut.TargetPath = '%ProgramFiles%\OpenTabletDriver\OpenTabletDriver.UX.Wpf.exe';" ^
  "$Shortcut.WorkingDirectory = '%ProgramFiles%\OpenTabletDriver';" ^
  "$Shortcut.Save();" ^
  "Remove-Item -Force $archive"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\OpenTabletDriver" /f /v DisplayName /t REG_SZ /d "OpenTabletDriver"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\OpenTabletDriver" /f /v InstallLocation /t REG_SZ /d "%ProgramFiles%\OpenTabletDriver"

:: WindowsInk for OpenTabletDriver
ECHO WindowsInk support for OpenTabletDriver...
PowerShell -Command "Invoke-WebRequest -Uri https://github.com/X9VoiD/vmulti-bin/releases/download/v1.0/VMulti.Driver.zip -OutFile '%TEMP%\VMulti-Driver.zip'"
PowerShell -Command "Expand-Archive -Path '%TEMP%\VMulti-Driver.zip' -DestinationPath '%TEMP%\VMulti-Driver' -Force"
CALL "%TEMP%\VMulti-Driver\install_hiddriver.bat"
PowerShell -Command "Invoke-WebRequest -Uri https://github.com/X9VoiD/VoiDPlugins/releases/latest/download/WindowsInk.zip -OutFile '%TEMP%\WindowsInk.zip'"
PowerShell -Command "Expand-Archive -Path '%TEMP%\WindowsInk.zip' -DestinationPath '%LOCALAPPDATA%\OpenTabletDriver\Plugins\Windows Ink' -Force"

:: Presets of OpenTabletDriver
ECHO Downloading OpenTabletDriver presets...
PowerShell -Command "Invoke-WebRequest -Uri !repo!/opentabletdriver/vertical-main.json -OutFile '%LOCALAPPDATA%\OpenTabletDriver\Presets\vertical-main.json'"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/opentabletdriver/vertical-second.json -OutFile '%LOCALAPPDATA%\OpenTabletDriver\Presets\vertical-second.json'"

:: Settings of OpenTabletDriver, using 'vertical-main.json' as default settings
ECHO Setting up OpenTabletDriver...
XCOPY "%LOCALAPPDATA%\OpenTabletDriver\Presets\vertical-main.json" "%LOCALAPPDATA%\OpenTabletDriver\settings.json" /-I /Y

:: Start minimized at startup
PowerShell -Command "" ^
  "$WshShell = New-Object -comObject WScript.Shell;" ^
  "$Shortcut = $WshShell.CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\Startup\OpenTabletDriver.lnk');" ^
  "$Shortcut.TargetPath = '%ProgramFiles%\OpenTabletDriver\OpenTabletDriver.UX.Wpf.exe';" ^
  "$Shortcut.WorkingDirectory = '%ProgramFiles%\OpenTabletDriver';" ^
  "$Shortcut.WindowStyle = 7;" ^
  "$Shortcut.Save()"


:: === NOWT ==
ECHO NOWT...
PowerShell -Command "" ^
  "$exe = 'NOWT-Installer.exe';" ^
  "$link = 'https://github.com/pwall2222/NOWT/releases/latest/download/' + $exe;" ^
  "$file = Join-Path -Path '%TEMP%' -ChildPath $exe;" ^
  "Invoke-WebRequest -Uri $link -OutFile $file;" ^
  "Start-Process -Wait $file '/SUPPRESSMSGBOXES', '/VERYSILENT';" ^
  "Remove-Item -Force $file"


:: === Deceive ==
ECHO Deceive...
MKDIR "%LOCALAPPDATA%\Deceive" 2>NUL
PowerShell -Command "" ^
  "$exe = 'Deceive.exe';" ^
  "$link = 'https://github.com/molenzwiebel/Deceive/releases/latest/download/' + $exe;" ^
  "$outfile = Join-Path -Path '%LOCALAPPDATA%\Deceive' -ChildPath $exe;" ^
  "Invoke-WebRequest -Uri $link -OutFile $outfile;" ^
  "$WshShell = New-Object -comObject WScript.Shell;" ^
  "$Shortcut = $WshShell.CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\Deceive.lnk');" ^
  "$Shortcut.TargetPath = $outfile;" ^
  "$Shortcut.Save()"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\Deceive" /f /v DisplayName /t REG_SZ /d "Deceive"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\Deceive" /f /v InstallLocation /t REG_SZ /d "%LOCALAPPDATA%\Deceive"


:: === Xournal++ ==
:: TODO: Winget report an incorrect hash on installation,
::       that's why we're installing it manually
:: ECHO Xournal++...
:: PowerShell -Command "" ^
::   "$repo = 'xournalpp/xournalpp';" ^
::   "$releases = \"https://api.github.com/repos/$repo/releases\";" ^
::   "$tag = (Invoke-WebRequest $releases | ConvertFrom-Json)[1].tag_name;" ^
::   "$file = \"xournalpp-$($tag.substring(1))-windows.zip\";" ^
::   "$link = \"https://github.com/$repo/releases/download/$tag/$file\";" ^
::   "$archive = 'xournalpp.zip';" ^
::   "$outfile = Join-Path -Path $env:TEMP -ChildPath $archive;" ^
::   "Invoke-WebRequest -Uri $link -OutFile $outfile;" ^
::   "cd $env:TEMP;" ^
::   "Expand-Archive -Path $archive -DestinationPath $env:TEMP -Force;" ^
::   "$exe = $env:TEMP + '\' + $file.Substring(0, $file.Length - 3) + 'exe';" ^
::   "Start-Process $exe /S;" ^
::   "Remove-Item -Force $outfile;" ^
::   "Remove-Item -Force $exe"


:: === Minecraft ==
:: Rename shortcut for Minecraft
RENAME "%APPDATA%\Microsoft\Windows\Start Menu\Programs\Prism Launcher.lnk" Minecraft.lnk


:: === Cubiomes viewer ==
ECHO Cubiomes viewer...
MKDIR "%LOCALAPPDATA%\cubiomes-viewer" 2>NUL
PowerShell -Command "" ^
  "$exe = 'cubiomes-viewer-static-win.exe';" ^
  "$link = 'https://github.com/Cubitect/cubiomes-viewer/releases/latest/download/' + $exe;" ^
  "$outfile = Join-Path -Path '%LOCALAPPDATA%\cubiomes-viewer' -ChildPath $exe;" ^
  "Invoke-WebRequest -Uri $link -OutFile $outfile;" ^
  "$WshShell = New-Object -comObject WScript.Shell;" ^
  "$Shortcut = $WshShell.CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\cubiomes-viewer.lnk');" ^
  "$Shortcut.TargetPath = $outfile;" ^
  "$Shortcut.Save()"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\cubiomes-viewer" /f /v DisplayName /t REG_SZ /d "cubiomes-viewer"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\cubiomes-viewer" /f /v InstallLocation /t REG_SZ /d "%LOCALAPPDATA%\cubiomes-viewer"


:: === Firefox configuration ==
:: Open and close Firefox for the first time, generating a profile
"%ProgramFiles%\Mozilla Firefox\firefox.exe"
TIMEOUT 5
TASKKILL /im firefox.exe /F

ECHO Firefox configuration...
FOR /F "usebackq delims=" %%i IN (`dir /B /S "%APPDATA%\Mozilla\Firefox\Profiles\*.default-release"`) DO SET "vbc=%%i"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/.mozilla/firefox/user.js -OutFile '!vbc!\user.js'"

:: Download addons settings in "Download" folder
PowerShell -Command "Invoke-WebRequest -Uri !repo!/.mozilla/firefox/extensions/SponsorBlockConfig.json -OutFile '%HOMEPATH%\Downloads\SponsorBlockConfig.json'"
PowerShell -Command "Invoke-WebRequest -Uri !repo!/.mozilla/firefox/extensions/auto-tab-discard-preferences.json -OutFile '%HOMEPATH%\Downloads\auto-tab-discard-preferences.json'"
ECHO La configuration des differents Addons de Firefox est presente dans le dossier Téléchargement (%HOMEPATH%\Downloads).


:: === WindowsAutoNightMode ==
ECHO WindowsAutoNightMode configuration...
MKDIR "%APPDATA%\AutoDarkMode" 2>NUL
PowerShell -Command "Invoke-WebRequest -Uri !repo!/.config/WindowsAutoNightMode/config.yaml -OutFile '%APPDATA%\AutoDarkMode\config.yaml'"
"%LOCALAPPDATA%\Programs\AutoDarkMode\adm-app\AutoDarkModeApp.exe"


:: === OBS ==
:: TODO: Replaced by NVidia Shadowplay
:: OBS replay buffer at startup
:: PowerShell -Command "$WshShell = New-Object -COM WScript.Shell;" ^
::                     "$Shortcut = $WshShell.CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\Startup\OBS.lnk');" ^
::                     "$Shortcut.TargetPath = '%ProgramFiles%\obs-studio\bin\64bit\obs64.exe';" ^
::                     "$Shortcut.WorkingDirectory = '%ProgramFiles%\obs-studio\bin\64bit';" ^
::                     "$Shortcut.Arguments = '--disable-missing-files-check --minimize-to-tray " ^
::                     "--startreplaybuffer --profile ""ReplayBuffer"""" --scene ""ReplayBuffer""""';" ^
::                     "$Shortcut.Save()"
:: :: Default shortcut should start default profile
:: CALL "!local!\fix_obs_shortcut.bat" yes
:: :: Allow system to go in sleep mode when OBS is running
:: powercfg -requestsoverride process obs64.exe display system awaymode


:: === miHoYo Games launcher ==
ECHO Collapse...
PowerShell -Command "" ^
  "$repo = 'CollapseLauncher/Collapse';" ^
  "$releases = \"https://api.github.com/repos/$repo/releases/latest\";" ^
  "$link = (Invoke-WebRequest $releases | ConvertFrom-Json)[0].assets.browser_download_url[0];" ^
  "$exe = 'collapse-installer.exe';" ^
  "$outFile = Join-Path -Path $env:TEMP -ChildPath $exe;" ^
  "Invoke-WebRequest -Uri $link -OutFile $outFile;" ^
  "Start-Process -Wait $outFile '/SUPPRESSMSGBOXES', '/VERYSILENT';" ^
  "Remove-Item -Force $outFile"

:: Games shortcut
CMD /c "!local!\fix_mihoyo_shortcut.bat" yes


:: === FiveM ==
ECHO FiveM...
PowerShell -Command "" ^
  "$baselink = 'https://runtime.fivem.net/client';" ^
  "$exe = 'FiveM.exe';" ^
  "$path = \"$env:LOCALAPPDATA\FiveM\";" ^
  "$outFile = Join-Path -Path $path -ChildPath $exe;" ^
  "Invoke-WebRequest -Uri \"https://runtime.fivem.net/client/$exe\" -OutFile $outFile;" ^
  "$WshShell = New-Object -comObject WScript.Shell;" ^
  "$Shortcut = $WshShell.CreateShortcut('%APPDATA%\Microsoft\Windows\Start Menu\Programs\FiveM.lnk');" ^
  "$Shortcut.WorkingDirectory = \"$path\";" ^
  "$Shortcut.TargetPath = $outFile;" ^
  "$Shortcut.Save()"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\fivem" /f /v DisplayName /t REG_SZ /d "FiveM"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Uninstall\fivem" /f /v InstallLocation /t REG_SZ /d "%LOCALAPPDATA%\FiveM"


:: === DaVinci Resolve ==
ECHO Lien utile pour télécharger la dernière version de DaVinci Resolve :
ECHO https://www.blackmagicdesign.com/support/family/davinci-resolve-and-fusion


:: === Drivers notice ==
ECHO Installe les pilotes, pour connaitre la liste des pilotes, utilise UserDiag https://userdiag.com/download
ECHO Pour NVidia, utilise NVC et DDU


:: === End message ==
ECHO ""
ECHO Fais un tour des parametres Windows, apres avoir fait toutes les mises a jour disponible sur le PC.
ECHO Enfin, redemarre l'ordinateur

PAUSE
EXIT /B